// ESPlayerPawn.uc

simulated function bool CalcCamera( float fDeltaTime, out vector out_CamLoc, out rotator out_CamRot, out float out_FOV )
{
        local vector CamStart, HitLocation, HitNormal, CamDirX, CamDirY, CamDirZ, CurrentCamOffset;
        local float DesiredCameraZOffset;

        CamStart = self.Location;
        CurrentCamOffset = self.CamOffset;

        DesiredCameraZOffset = (Health > 0) ? - 1.2 * GetCollisionHeight() + Mesh.Translation.Z : 0.f;
        CameraZOffset = (fDeltaTime < 0.2) ? - DesiredCameraZOffset * 5 * fDeltaTime + (1 - 5*fDeltaTime) * CameraZOffset : DesiredCameraZOffset;

        if ( Health <= 0 )
        {
                CurrentCamOffset = vect(0,0,0);
                CurrentCamOffset.X = GetCollisionRadius();
        }

        CamStart.Z += CameraZOffset;
        GetAxes(out_CamRot, CamDirX, CamDirY, CamDirZ);
        CamDirX *= CurrentCameraScale;

        if ( (Health <= 0) || bFeigningDeath ) {
                // Move camera to prevent pinning by world
                // @todo fixmesteve. If FindSpot fails, then (rarely does) camera pinned continously.
                FindSpot(GetCollisionExtent(), CamStart);
        }

        if (CurrentCameraScale < CameraScale) {
                CurrentCameraScale = FMin(CameraScale, CurrentCameraScale + 5 * FMax(CameraScale - CurrentCameraScale, 0.3)*fDeltaTime);
        }
        else if (CurrentCameraScale > CameraScale) {
                CurrentCameraScale = FMax(CameraScale, CurrentCameraScale - 5 * FMax(CameraScale - CurrentCameraScale, 0.3)*fDeltaTime);
        }

        if (CamDirX.Z > GetCollisionHeight()) {
                CamDirX *= square(cos(out_CamRot.Pitch * 0.0000958738)); // 0.0000958738 = 2*PI/65536
        }

        out_CamLoc = CamStart - CamDirX*CurrentCamOffset.X + CurrentCamOffset.Y*CamDirY + CurrentCamOffset.Z*CamDirZ;

        if (Trace(HitLocation, HitNormal, out_CamLoc, CamStart, false, vect(12,12,12)) != None) {
                out_CamLoc = HitLocation;
        }

        return true;
}